內(nèi)部EEPROM讀寫驗(yàn)證
;本實(shí)戰(zhàn)的目的是讓大家熟悉PIC16F87X內(nèi)部EEPROM的讀寫方法
;項(xiàng)目實(shí)現(xiàn)的功能：對(duì)于地址為00H-3FH的64個(gè)EEPROM數(shù)據(jù)存儲(chǔ)單元，分別將數(shù)據(jù)0-63依次燒寫進(jìn)去，然后再循環(huán)讀出，顯示在8只LED發(fā)光二極管上
;程序文件名“MCD-EMP1.ASM"
;程序清單如下:
;************************************
STATUS   EQU 3H       ;定義狀態(tài)寄存器地址
RP0      EQU 5H       ;定義頁選位RP0的位地址
RP1      EQU 6H       ;定義頁選位RP1的位地址
Z        EQU 2H       ;定義0狀態(tài)位的位地址
PORTC    EQU 7H       ;定義RC口數(shù)據(jù)寄存器地址
TRISC    EQU 87H      ;定義RC口方向控制寄存器地址
EECON1   EQU 18CH     ;定義寫控制寄存器1的地址
EECON2   EQU 18DH     ;定義寫控制寄存器2的地址
EEDATA   EQU 10CH     ;定義讀/寫數(shù)據(jù)寄存器地址
EEADR    EQU 10DH     ;定義讀/寫地址寄存器地址
RD       EQU  0       ;定義讀啟動(dòng)控制位位地址
WR       EQU  1       ;定義寫啟動(dòng)控制位位地址
WREN     EQU  2       ;定義寫使能控制位位地址
EEPGD    EQU  7       ;定義訪問目標(biāo)選擇控制位位址
F        EQU  1       ;定義目標(biāo)寄存器為RAM的指示符
W        EQU  0       ;定義目標(biāo)寄存器為W的指示符
ADDR     EQU  70H     ;定義地址變量
DATA1    EQU  71H     ;定義數(shù)據(jù)變量
;*************************************
    ORG     0000H        ;
    NOP                  ;放置一條ICD必須的空操作指令
    GOTO    MAIN         ;
    ORG     0008H        ;
MAIN
    BCF     STATUS,RP1   ;選體1為當(dāng)前體
    BSF     STATUS,RP0   ;
    MOVLW   00H          ;設(shè)定RC全部為輸出
    MOVWF   TRISC        ;
    BSF     STATUS,RP1   ;體3為當(dāng)前體
    CLRF    ADDR         ;地址變量清0
    CLRF    DATA1        ;數(shù)據(jù)變量清0
WRITE
    BSF     STATUS,RP1   ;選定體3
    BTFSC   EECON1,WR    ;上一次寫操作是否完成
    GOTO    $-1          ;否！返回繼續(xù)檢測
    BCF     STATUS,RP0   ;選定體2
    MOVF    ADDR,W       ;取地址
    MOVWF   EEADR        ;送地址寄存器
    MOVF    DATA1,W      ;取數(shù)據(jù)
    MOVWF   EEDATA       ;送數(shù)據(jù)寄存器
    BSF     STATUS,RP0   ;選定體3
    BCF     EECON1,EEPGD ;選定EEPROM為訪問對(duì)向
    BSF     EECON1,WREN  ;開放寫操作使能控制
    MOVLW    55H         ;
    MOVWF   EECON2       ;送55H到寄存器EECON2（讀寫內(nèi)部EEPROM，這句是固定的）
    MOVLW   0AAH         ;
    MOVWF   EECON2       ;送AAH到寄存器EECON2（讀寫內(nèi)部EEPROM，這句是固定的）
    BSF     EECON1,WR    ;啟動(dòng)寫操作
    BCF     EECON1,WREN  ;禁止寫操作發(fā)生
    INCF    DATA1,F      ;數(shù)據(jù)遞增
    INCF    ADDR,F       ;地址遞增
    MOVF    ADDR,W       ;
    XORLW   D'64'        ;將當(dāng)前地址與64比較
    BTFSS   STATUS,Z     ;檢測=64否
    GOTO    WRITE        ;否！繼續(xù)寫后面單元
READ1
    DECF    ADDR,F       ;地址遞減
    BCF     STATUS,RP0   ;選體2為當(dāng)前體
    BSF     STATUS,RP1   ;
    MOVF    ADDR,W       ;取地址
    MOVWF   EEADR        ;送地址寄存器
    BSF     STATUS,RP0   ;選體3為當(dāng)前體
    BCF     EECON1,EEPGD  ;選定EEPROM為訪問對(duì)象
    BSF     EECON1,RD     ;啟動(dòng)讀操作
    BCF     STATUS,RP0    ;體2為當(dāng)前體
    MOVF    EEDATA,W      ;取數(shù)據(jù)
    BCF     STATUS,RP1    ;體0為當(dāng)前體
    MOVWF   PORTC         ;送顯LED
    CALL    DELAY         ;調(diào)用廷時(shí)子程序
    MOVF    ADDR,F        ;檢測當(dāng)前地址
    BTFSS   STATUS,Z      ;是否為0？是！跳一步
    GOTO    READ1         ;否！返回繼續(xù)讀出和顯示
READ2
    INCF    ADDR,F        ;地址遞增
    BCF     STATUS,RP0    ;選體2為當(dāng)前體
    BSF     STATUS,RP1    ;
    MOVF    ADDR,W        ;取地址
    MOVWF   EEADR         ;送地址寄存器
    BSF     STATUS,RP0     ;選體3為當(dāng)前體
    BCF     EECON1,EEPGD   ;選定EEPROM為訪問對(duì)象
    BSF     EECON1,RD      ;啟動(dòng)讀操作
    BCF     STATUS,RP0     ;體2為當(dāng)前體
    MOVF    EEDATA,W       ;取數(shù)據(jù)
    BCF     STATUS,RP1     ;體0為當(dāng)前體
    MOVWF   PORTC          ;送顯LED
    CALL    DELAY          ;調(diào)用廷時(shí)子程序
    MOVF    ADDR,W         ;檢測當(dāng)前地址與64比較
    XORLW   D'64'          ;
    BTFSS   STATUS,Z       ;是否等于64
    GOTO    READ2          ;否！返回繼續(xù)讀出和顯示
    GOTO    READ1          ;返回大循環(huán)起點(diǎn)
;******************************************
DELAY
    MOVLW    0             ;
    MOVWF    72H           ;將外層循環(huán)參數(shù)值256送外層循環(huán)寄存器
DELAY1
    MOVLW     0            ;將內(nèi)層循環(huán)參數(shù)值256送內(nèi)層循環(huán)寄存器
    MOVWF    73H           ;
    DECFSZ   73H,1         ;遞減廷時(shí)程序
    GOTO     $-1           ;
    DECFSZ   72H,1         ;
    GOTO     DELAY1        ;
    RETURN
;********************************************
    END
;*****************************************************
;    進(jìn)入該實(shí)戰(zhàn)演練的工序流程如下:
;    1.創(chuàng)建源文件和編輯源文件;在此介紹一種不同于前面講的創(chuàng)建源文件的方法,用Windows附件中的”記事本”
;   這個(gè)為大家所熟知和好用的文件編輯器,并且可以方便的加入中文注釋.不過有兩點(diǎn)需要注意,一是注釋前面的
;   分號(hào)”;”必須用西文半角輸入;二是必須用”.asm”擴(kuò)展名存儲(chǔ)到事先建立的一個(gè)專用子目錄下.
;    2.打開MPLAB集成開發(fā)環(huán)境:首先在WINDOWS環(huán)境下,選用開始>程序>Microchip MPLAB>MPLAB命令,啟動(dòng)MPLAB
;   并進(jìn)入MPLAB的桌面.
;    3.創(chuàng)建項(xiàng)目:選用菜單File>New或Project>New Project,在事先建立的一個(gè)專用子目錄下創(chuàng)建一個(gè)新項(xiàng)目,將
;   用記事本創(chuàng)建的源文件加入到該項(xiàng)目中.
;    4.建立項(xiàng)目中的目標(biāo)文件:選擇菜單Project >Build All(項(xiàng)目>建立所有文件),MPLAB將自動(dòng)調(diào)用MPASM將項(xiàng)目
;   文件管理下的源文件(.asm)匯編成十六進(jìn)制的目標(biāo)文件(.hex).
;    5.ICD參數(shù)設(shè)置:通過菜單命令Project>Edit Project或者Option>Development Mode,將開發(fā)模式設(shè)置為
;   ”MPLAB ICD Debugger”,點(diǎn)擊OK按鈕,打開ICD的工作窗口,在調(diào)試階段,可以按照說明書圖2-10設(shè)置各項(xiàng),但需注意
;   OSCILLATOR應(yīng)設(shè)置為XT方式,尤其需要說明的是，選中“Enable Debug Mode”（使能調(diào)試模式）選項(xiàng)，在向目
;   標(biāo)單片機(jī)燒寫機(jī)器碼程序時(shí)，會(huì)將調(diào)試臨控程序同時(shí)寫入單片機(jī)的指定程序存儲(chǔ)器區(qū)域，然后才允許用ICD方式調(diào)試。
;    6.電路設(shè)置:將演示板的S1全部拔到ON，S13全部拔到OFF，S4,S5全部拔到OFF ，LCD不用插在演示板上，
;   將用于選擇頻率的插針跳線插到”XT OSC”位置上.
;    7.向目標(biāo)單片機(jī)燒寫目標(biāo)程序:用戶在點(diǎn)擊功能按鈕”Program”向目標(biāo)單片機(jī)燒寫機(jī)器碼程序時(shí),會(huì)等待一段時(shí)間，
;   并且在條狀的狀態(tài)信息欄中，出現(xiàn)提示信息。有一點(diǎn)需要引起注意，就是PIC16F87X單片機(jī)的FLASH程序存儲(chǔ)器的擦寫
;   周期是有限的，大約為1000次，應(yīng)盡量節(jié)省它的使用壽命。
;    8.運(yùn)行和調(diào)試用戶程序和用戶電路:在各項(xiàng)參數(shù)設(shè)置好后,將ICD的工作窗口最小化,利用前面講的”運(yùn)行及調(diào)試”中介
;   紹的幾種方法進(jìn)行調(diào)試.當(dāng)用自動(dòng)單步方式調(diào)試時(shí),建議臨時(shí)禁止廷時(shí)子程序發(fā)揮作用,具體的方法是,可在CALL DELAY指
;   令前添加一個(gè)分號(hào),并且重新匯編一次.為了學(xué)習(xí)目的,在調(diào)試過程中可以人為地加入一些軟件漏洞(BUG)或硬件故障,來模
;   仿單片機(jī)端口引腳的片內(nèi)或片外故障.
;    9.定型燒寫目標(biāo)單片機(jī);經(jīng)過多次重復(fù)上述步驟的反復(fù)修改和調(diào)試,使得程序和電路在聯(lián)機(jī)狀態(tài)完全正常,這時(shí)可以進(jìn)行
;   定型燒寫,即將ICD窗口中的”Enable Debug Mode”(使能調(diào)試模式)選項(xiàng)消除,不再將調(diào)試臨控程序?qū)懭雴纹瑱C(jī)中.
;    10.獨(dú)立運(yùn)行驗(yàn)收:上一步中的燒寫過程完成后,即可將ICD模塊和ICD仿真頭(或演示板)之間的6芯電纜斷開,讓單片機(jī)在
;   演示板獨(dú)立運(yùn)行,觀察實(shí)際效果.