單鍵觸發(fā)8位二進(jìn)制累加計(jì)數(shù)器
;該程序的目的是讓大家熟悉輸入、輸出端口的使用
;該程序的功能是把演示板當(dāng)做一個(gè)按鍵計(jì)數(shù)器。剛剛接通電源時(shí)，8只發(fā)光二極管都不亮。
;表示計(jì)數(shù)器初值為0，當(dāng)按下開關(guān)S3（RB0）時(shí)，計(jì)數(shù)器的值加1，發(fā)光二極管D3點(diǎn)亮，表示值1，然后松開
;按鈕；再次按下開關(guān)S3（RB0）時(shí)，計(jì)數(shù)器的值又加1，發(fā)光二極管D4點(diǎn)亮，表示值2，依次類推，反復(fù)循環(huán)。
;程序清單：
;*************************************************
status    equ     3h   ;定義狀態(tài)寄存器地址
portb     equ     6h   ;定義端口B的數(shù)據(jù)寄存器地址
trisb     equ     86h  ;定義端口B的方向控制寄存器地址
portc     equ     7h   ;定義端口C的數(shù)據(jù)寄存器地址
trisc     equ     87h  ;定義端口C的方向控制寄存器地址
data1     equ     20h  ;定義一個(gè)廷時(shí)變量寄存器
data2     equ     21h  ;定義另一個(gè)廷時(shí)變量寄存器
n1        equ     d'13'  ;定義一個(gè)外層循環(huán)廷時(shí)常數(shù)
n2        equ     0ffh   ;定義一個(gè)內(nèi)層廷時(shí)常數(shù)
rp0       equ     5h     ;定義狀態(tài)寄存器的頁(yè)選位RP0
;*************************************************
          org 000h       ;定義程序存放區(qū)域的起始地址
          nop            ;放置一條ICD必須的空操作指令
          bsf status,rp0  ;設(shè)置文件寄存器體1
          movlw 00h       ;將端口C的方向控制碼00H先送W
          movwf trisc     ;再轉(zhuǎn)到方向寄存器，將其設(shè)置為輸出
          movlw 0ffh      ;同理，將端口B設(shè)置為輸入
          movwf trisb     ;
          bcf status,rp0  ;恢復(fù)到文件寄存器體0
          movlw 00h       ;送計(jì)器初值00H到RC口顯示
          movwf portc     ;
check     btfsc portb,0   ;測(cè)試S3按下否？是！跳過(guò)下條指令
          goto check      ;否！則循環(huán)檢測(cè)
          call delay      ;調(diào)用廷時(shí)子程序，消除按鈕抖動(dòng)的影響
          btfsc portb,0   ;再次測(cè)試S3按下否？是！跳過(guò)下條指令
          goto check      ;否！則循不檢測(cè)
          incf portc,1    ;端口C的數(shù)據(jù)寄存器加1，并送LED顯示
check1    btfss portb,0   ;測(cè)試S3斷開否？是！跳過(guò)下條指令
          goto check1     ;否！則循不檢測(cè)
          call delay      ;調(diào)用廷時(shí)子程序，消除按鈕抖動(dòng)的影響
          btfss portb,0   ;再次測(cè)試S3斷開否？是！跳過(guò)下條指令
          goto check1     ;否！則循不檢測(cè)
          goto check      ;返回
;*************10MS廷時(shí)子程序************************
delay                     ;子程序名，也是子程序入口地址
          movlw n1        ;將外層循環(huán)參數(shù)值送到DATA1
          movwf data1     ;
lp0       movlw n2        ;將內(nèi)層循環(huán)參數(shù)值送到DATA2
          movwf data2     ;
lp1       decfsz data2,1  ;變量DATA2內(nèi)容遞減，若為0則跳躍
          goto lp1        ;跳轉(zhuǎn)到LP1
          decfsz data1,1  ;變量DATA1內(nèi)容遞減，若為0則跳躍
          goto lp0        ;跳轉(zhuǎn)到LP0
          return          ;返回主程序
          end             ;源程序結(jié)束
;***************************************************
;    進(jìn)入該實(shí)戰(zhàn)演練的工序流程如下:
;    1.軟硬件的安裝:按照本說(shuō)明書前面講的”MPLAB-ICD的安裝和使用”一節(jié)內(nèi)介紹的方法操作即可.
;    2.創(chuàng)建源文件和編輯源文件;在此介紹一種不同于前面講的創(chuàng)建源文件的方法,用Windows附件中的”記事本”
;   這個(gè)為大家所熟知和好用的文件編輯器,并且可以方便的加入中文注釋.不過(guò)有兩點(diǎn)需要注意,一是注釋前面的
;   分號(hào)”;”必須用西文半角輸入;二是必須用”.asm”擴(kuò)展名存儲(chǔ)到事先建立的一個(gè)專用子目錄下.
;    3.打開MPLAB集成開發(fā)環(huán)境:首先在WINDOWS環(huán)境下,選用開始>程序>Microchip MPLAB>MPLAB命令,啟動(dòng)MPLAB
;   并進(jìn)入MPLAB的桌面.
;    4.創(chuàng)建項(xiàng)目:選用菜單File>New或Project>New Project,在事先建立的一個(gè)專用子目錄下創(chuàng)建一個(gè)新項(xiàng)目,將
;   用記事本創(chuàng)建的源文件加入到該項(xiàng)目中.
;    5.建立項(xiàng)目中的目標(biāo)文件:選擇菜單Project >Build All(項(xiàng)目>建立所有文件),MPLAB將自動(dòng)調(diào)用MPASM將項(xiàng)目
;   文件管理下的源文件(.asm)匯編成十六進(jìn)制的目標(biāo)文件(.hex).
;    6.ICD參數(shù)設(shè)置:通過(guò)菜單命令Project>Edit Project或者Option>Development Mode,將開發(fā)模式設(shè)置為
;   ”MPLAB ICD Debugger”,點(diǎn)擊OK按鈕,打開ICD的工作窗口,在調(diào)試階段,可以按照說(shuō)明書圖2-10設(shè)置各項(xiàng),但需注意
;   OSCILLATOR應(yīng)設(shè)置為XT方式,尤其需要說(shuō)明的是，選中“Enable Debug Mode”（使能調(diào)試模式）選項(xiàng)，在向目
;   標(biāo)單片機(jī)燒寫機(jī)器碼程序時(shí)，會(huì)將調(diào)試臨控程序同時(shí)寫入單片機(jī)的指定程序存儲(chǔ)器區(qū)域，然后才允許用ICD方式調(diào)試。
;    7.電路設(shè)置:將演示板的S1全部拔到ON，S4全部拔到OFF，S13的第1拔到ON、第5、第6、第7全部拔到OFF ，LCD不要插在演示板上，
;   以使端口C只與8只發(fā)光二極管接通;將用于選擇頻率的插針跳線插到”XT OSC”位置上.
;    8.向目標(biāo)單片機(jī)燒寫目標(biāo)程序:用戶在點(diǎn)擊功能按鈕”Program”向目標(biāo)單片機(jī)燒寫機(jī)器碼程序時(shí),會(huì)等待一段時(shí)間，
;   并且在條狀的狀態(tài)信息欄中，出現(xiàn)提示信息。有一點(diǎn)需要引起注意，就是PIC16F87X單片機(jī)的FLASH程序存儲(chǔ)器的擦寫
;   周期是有限的，大約為1000次，應(yīng)盡量節(jié)省它的使用壽命。
;    9.運(yùn)行和調(diào)試用戶程序和用戶電路:在各項(xiàng)參數(shù)設(shè)置好后,將ICD的工作窗口最小化,利用前面講的”運(yùn)行及調(diào)試”中介
;   紹的幾種方法進(jìn)行調(diào)試.當(dāng)用自動(dòng)單步方式調(diào)試時(shí),建議臨時(shí)禁止廷時(shí)子程序發(fā)揮作用,具體的方法是,可在CALL DELAY指
;   令前添加一個(gè)分號(hào),并且重新匯編一次.為了學(xué)習(xí)目的,在調(diào)試過(guò)程中可以人為地加入一些軟件漏洞(BUG)或硬件故障,來(lái)模
;   仿單片機(jī)端口引腳的片內(nèi)或片外故障.
;    10.定型燒寫目標(biāo)單片機(jī);經(jīng)過(guò)多次重復(fù)上述步驟的反復(fù)修改和調(diào)試,使得程序和電路在聯(lián)機(jī)狀態(tài)完全正常,這時(shí)可以進(jìn)行
;   定型燒寫,即將ICD窗口中的”Enable Debug Mode”(使能調(diào)試模式)選項(xiàng)消除,不再將調(diào)試臨控程序?qū)懭雴纹瑱C(jī)中.
;    11.獨(dú)立運(yùn)行驗(yàn)收:上一步中的燒寫過(guò)程完成后,即可將ICD模塊和ICD仿真頭(或演示板)之間的6芯電纜斷開,讓單片機(jī)在
;   演示板獨(dú)立運(yùn)行,觀察實(shí)際效果.
;
;